Created and coded completely in SuperCollider. Code follows:
------

(
d=Bus.audio(s, 2);

SynthDef(\fmLead, {|gain=0.5, freq=200, dur=0.5, modamt=0.82, fcut=500, fenvamt=20, fenvdur=0.2, delsend=1|
var sig = MoogFF.ar(VarSaw.ar(freq*Mix.ar(SinOsc.ar([freq/4, freq/2], 0, modamt, 1)), 0, 1, gain), XLine.ar(fenvamt*fcut, fcut, fenvdur), 0) * EnvGen.ar(Env.new([0,1,1,0], [0.001, dur-0.011, 0.01]), doneAction: 2);
Out.ar(0, sig.dup);
Out.ar(d, sig.dup*delsend);
}).add;

SynthDef(\delay, {|timeL=0.230, timeR=0.240, fdbk=0.7, delmod=0.005|
var in = In.ar(d, 2);
var ret = LocalIn.ar(2);
var mod = SinOsc.ar(0.25, 0, delmod);
var sig = DelayL.ar(in+ret, 1, [timeL+mod, timeR+mod]);
LocalOut.ar(sig*fdbk);
Out.ar(0, sig);
}).add;
)

TempoClock.default.tempo = 128/120;

(

var p1 = Pbind(\instrument, \fmLead,

\midinote, Pseq([60, 67, 60, 67, 60, 67, 60, 58, 70, 48], inf),
\dur, Pseq([Pseq([1/8, 2/8], 16), 1/4], inf),
\addAction, 0,
\delsend, 0.5,
\fcut, Pseq(Array.series(88, 150, 5).mirror, inf),
\fenvdur, Pseq(Array.series(88, 0.05, 0.005).mirror, inf),
\modamt, 0.6,
\gain, 0.25
);

var p2 = Pbind(\instrument, \fmLead,

\midinote, Pseq([Pn([44, 56, 63], 11), Pn([48, 60, 67], 10), [48, 60, 70]], inf),
\dur, Pseq([Pn(3/8, 10), 1/4], inf),
\addAction, 0,
\gain, 0.35,
\delsend, 0.25,
\fcut, Pseq(Array.series(44, 150, 20).mirror, inf),
\fenvamt, 10,
\fenvdur, 0.25,
\modamt, 0.8
);
Synth.new(\delay, [fdbk: 0.7]);
p = Ppar([p1,p2], inf).play;
)
(
p.stop
)